VBA - Belirli bir üstbilgiye sahip bir sütun bulun ve bu sütundaki tüm satırların toplamını bul

Question

Geniş bir sayfam var. Bu sayfada birden fazla filtre ayarlamalıyım. Filtreler belirlendikten sonra, "Nov" sütun başlığına sahip olan ve bu sütundaki değerlerin toplamını elde eden ve bu belirli toplam değeri farklı bir çalışma sayfasına içe aktaran belirli bir sütunu bulmak zorundayım. Filtreleri, çok sayıda sütuna filtreleyebileceğim yere kadar yazdım, ancak sütun başlığını bulup bu sütunu eklemeyi zor buluyorum. Şimdiye kadar yazdığım kod aşağıdadır.

Sub Button2_Click() 
Dim colName As Long 
Dim colName1 As Long 
Dim colName2 As Long 
Dim r As Long 

SearchV = Range("A8:DD8").Find(What:="Nov", LookIn:=xlValues, LookAt:=xlWhole, _ 
MatchCase:=False, SearchFormat:=False).Column 

lastrow = Cells(Rows.Count, SearchV).End(xlUp).Row 

colName = Range("A8:DD8").Find(What:="Teams", LookIn:=xlValues, LookAt:=xlWhole, _ 
MatchCase:=False, SearchFormat:=False).Column 

colName1 = Range("A8:DD8").Find(What:="Items", LookIn:=xlValues, LookAt:=xlWhole, _ 
MatchCase:=False, SearchFormat:=False).Column 

colName2 = Range("A8:DD8").Find(What:="Domain", LookIn:=xlValues, LookAt:=xlWhole, _ 
MatchCase:=False, SearchFormat:=False).Column 

ActiveSheet.Range("$A$8:$DD$9999").AutoFilter Field:=colName, Criteria1:="ST Test",  Operator:=xlOr, Criteria2:="" 
ActiveSheet.Range("$A$8:$DD$9999").AutoFilter Field:=colName1, Criteria1:="Variance", Operator:=xlOr, Criteria2:="(Blanks)" 
ActiveSheet.Range("$A$8:$DD$9999").AutoFilter Field:=colName2, Criteria1:="9S", Operator:=xlOr, Criteria2:="(Blanks)" 

Sütun başlıkları her zaman 8. satıra başlar. Yukarıdaki satırlarda bazı utangaç bilgiler mevcut. Yani istediğim, 'Nov' sütununun H satırında olduğunu varsayalım. Toplam, H9'dan son satırın sonuna kadar hesaplanmalıdır. Sütun 'H' sütununda olduğunda bu formülü kullandım.

Cells(lastrow + 1, colName3).Formula = "=SUBTOTAL(9,H9:H" & lastrow & ")" 

Ama sütun 'Kasım' daima 'H' satırında mevcut olmayacaktır, bu yüzden dinamik sütun almaya kodumu nasıl değiştirileceğini anlamaya muktedir değilim.

Answer 1

Nesnelerinizi tam olarak nitelendirdiğinizden ve ayrıca .Find'un bir şey döndürüp döndürmediğini kontrol ettiğinizden emin olun. İşte bir örnek.

en bu

Şimdi Yardımlarınız Siddh için bu kodu

Option Explicit 

Sub Sample() 
    Dim ws As Worksheet 
    Dim aCell As Range, Rng As Range 
    Dim col As Long, lRow As Long 
    Dim colName As String 

    '~~> Change this to the relevant sheet 
    Set ws = ThisWorkbook.Sheets("Sheet1") 

    With ws 
     Set aCell = .Range("A8:DD8").Find(What:="Nov", LookIn:=xlValues, LookAt:=xlWhole, _ 
        MatchCase:=False, SearchFormat:=False) 

     '~~> If Found 
     If Not aCell Is Nothing Then 
      col = aCell.Column 
      colName = Split(.Cells(, col).Address, "$")(1) 

      lRow = .Range(colName & .Rows.Count).End(xlUp).Row 

      '~~> This is your range 
      Set Rng = .Range(colName & "8:" & colName & lRow) 

      Debug.Print Rng.Address 
     '~~> If not found 
     Else 
      MsgBox "Nov Not Found" 
     End If 
    End With 
End Sub 

Çıktı