Bir Windows makinesinde yüklü tüm web tarayıcılarını listeleme

Question

Makinemde (ve kullanıcı başına) yüklenen tüm web tarayıcılarını (ad, yürütülebilir, varsayılan evet/hayır) listelemek için yaygın yöntem/api var mı ve nasıl yapılır varsayılan web tarayıcısı hangisi olduğunu öğrenmek?

Ve MSDN'deki How to find all the browsers installed on a machine: How to Register an Internet Browser or Email Client With the Windows Start Menu web tarayıcıları altında kendilerini kayıt gerektiğini bildiren HKLM\SOFTWARE\Clients\StartMenuInternet (ve HKCU)

gerçekten ortak/doğru bir yaklaşım mı

Ben bu soruyu gördük? (Ve evet, herhangi bir katı uygulama dışarıda mı?)

---

Amacım (varsayılan gösterir) kullanıcının makinesinde yüklü tüm web tarayıcıların bir listesini içeren bir açılır menü oluşturmak ve izin vermektir Kullanıcı, HTML dosyasını/URL'lerini mevcut harici web tarayıcısından biriyle tarayacak.

Answer 1

Bunu

procedure ListRegisteredBrowsers(List: TStrings); 
var 
    reg: TRegistry; 
    ki: TRegKeyInfo; 
    i: Integer; 
    keyname: string; 
    len: DWORD; 
begin 
    reg := TRegistry.Create; 
    try 
    reg.RootKey := HKEY_LOCAL_MACHINE; 
    if not Reg.KeyExists('\SOFTWARE\Clients\StartMenuInternet') then Exit; 
    if not Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', false) then 
     raise Exception.Create('ListRegisteredBrowsers: Could not open registry key.'); 
    if not reg.GetKeyInfo(ki) then 
     raise Exception.Create('ListRegisteredBrowsers: Could not obtain registry key information.'); 
    List.Clear; 
    SetLength(keyname, len); 
    for i := 0 to ki.NumSubKeys - 1 do 
    begin 
     len := ki.MaxSubKeyLen + 1; 
     if RegEnumKeyEx(reg.CurrentKey, i, PChar(keyname), len, nil, nil, nil, nil) <> ERROR_SUCCESS then 
     RaiseLastOSError; 
     if reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet\' + keyname, false) then 
     List.Add(reg.ReadString('')); 
     Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', true); 
    end; 
    finally 
    reg.Free; 
    end; 
end; 

ve

function GetDefaultBrowser: string; 
var 
    reg: TRegistry; 
begin 
    result := ''; 
    reg := TRegistry.Create; 
    try 
    reg.RootKey := HKEY_CURRENT_USER; 
    if Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', false) then 
     result := reg.ReadString('') 
    else 
    begin 
     reg.RootKey := HKEY_LOCAL_MACHINE; 
     if Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', false) then 
     result := reg.ReadString('') 
    end; 
    reg.RootKey := HKEY_LOCAL_MACHINE; 
    if Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet\' + result, false) then 
     result := reg.ReadString(''); 
    finally 
    reg.Free; 
    end; 
end; 

Testi gibi bir şey yapabileceğini: işlemek için kurulan her ne dayalı

procedure TForm1.Button1Click(Sender: TObject); 
var 
    sl: TStringList; 
    i: Integer; 
    DefBrw: string; 
begin 
    DefBrw := GetDefaultBrowser; 
    sl := TStringList.Create; 
    try 
    ListRegisteredBrowsers(sl); 
    Memo1.Lines.BeginUpdate; 
    for i := 0 to sl.Count - 1 do 
     if SameText(sl[i], DefBrw) then 
     Memo1.Lines.Add(sl[i] + ' (Default)') 
     else 
     Memo1.Lines.Add(sl[i]); 
    Memo1.Lines.EndUpdate; 
    finally 
    sl.Free; 
    end; 
end; 

Answer 2

Bu yöntem, Başlat Menüsü İnternet Uygulamaları olarak kaydedilen tüm tarayıcıları bulur. Uygulamada, tüm büyük tarayıcılar kendilerini bu şekilde kaydettikleri için yeterli olacaktır. Bir tarayıcı kendisini Başlat Menüsü İnternet Uygulamaları olarak kaydetmeyi başaramazsa, Windows'un bunu fark edemediği ve bu tarayıcıyı kullanıcıya sunma şansı yoktur.

hepsini açıklıyor MSDN konu burada: http://msdn.microsoft.com/en-us/library/windows/desktop/dd203067.aspx

Windows XP ve Windows Vista'da Başlat menüsü varsayılan Internet (tarayıcı) ve E-posta (posta) istemcileri için ayrılmış yuvaları içeren, birlikte Genelde Başlat Menüsü İnternet Uygulamaları olarak bilinir. Başlat Menüsü İnternet Uygulamaları olarak kaydedilen uygulamalar, sistem genelinde (makine başına) bunu yapar. Windows Vista'da, kullanıcı, kullanıcı başına varsayılanlarını ayarlamak için Varsayılan Programlar özelliğini kullanabilir.