Bir klasöre Zip

Question

VBScript'te bir klasörü yukarı ZIP çalışıyorum ve çalışmıyor gibi görünüyor. Eminim başlık dosyasını doğru şekilde oluşturuyorum.

Gerçek dosyayı doğru şekilde oluşturur, yalnızca dosyayı sıkıştırmaz.

Herkes herhangi bir fikir var:

Sub ArchiveFolder (folder) 

    Dim fso, wShell, sApp, zipFile 

    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set wShell = CreateObject("WScript.Shell") 
    Set sApp = CreateObject("Shell.Application") 
    Set zipFile = fso.CreateTextFile(folder & ".zip") 

    ' Write zip file header. 
    zipFile.Write "PK" & Chr(5) & Chr(6) & String(18, 0) 
    zipFile.Close 

    sApp.NameSpace(folder & ".zip").CopyHere folder 

End Sub 

Answer 1

cevap ben here buldum. Büyü, komut dosyasının Shell'in işini yapmasını beklediği son Do..Loop'dur.

ArchiveFolder "sub\foo.zip", "..\baz" 

Sub ArchiveFolder (zipFile, sFolder) 

    With CreateObject("Scripting.FileSystemObject") 
     zipFile = .GetAbsolutePathName(zipFile) 
     sFolder = .GetAbsolutePathName(sFolder) 

     With .CreateTextFile(zipFile, True) 
      .Write Chr(80) & Chr(75) & Chr(5) & Chr(6) & String(18, chr(0)) 
     End With 
    End With 

    With CreateObject("Shell.Application") 
     .NameSpace(zipFile).CopyHere .NameSpace(sFolder).Items 

     Do Until .NameSpace(zipFile).Items.Count = _ 
       .NameSpace(sFolder).Items.Count 
      WScript.Sleep 1000 
     Loop 
    End With 

End Sub 

Answer 2

sizin argüman kontrol edin. folder, zip dosyasına koymak istediğiniz nesnenin yolu olmalıdır. Bir klasör nesnesi ise, folder.Path kullanmak zorundasınız, çünkü varsayılan klasör nesnesi yöntemi Name ve CopyHere nesneyi yalnızca adıyla bulamıyor.

Bunu kontrol etmek için fonksiyona bazı hata ayıklama ifadeleri ekleyebilirsiniz:

WScript.Echo TypeName(folder) 
If fso.FolderExists(folder) Then 
    WScript.Echo folder & " exists." 
Else 
    WScript.Echo folder & " doesn't exist." 
End If 

Answer 3

Eğer

oShell.Run "%comspec% /c c:\windows\7za.exe a " & oFile &".zip " & oFile & " -tzip",,True

Kaynak http://www.scriptlook.com/zip-large-files-in-a-directory-2/