Perl dizisini sıralamak istiyorum, ancak sonuç sıralanmamış

Question

Sıralamak istediğim bir dizi dizim var. A dizisinin her elemanı 3 öğeli bir dizidir. Ben artan düzende bir sıralamak istiyorum

my @A = ([2,3,1], [1,2,3], [1,0,2], [3,1,2], [2,2,4]); 

: gibi Dizi A görünüyor. 2 elemanı karşılaştırırken, ilk sayı kullanılır. Bir kravat varsa, ikinci sayı kullanılır ve daha sonra üçüncü sayı.

İşte kodum. 2 elemanı karşılaştırmak için 'cmpfunc' işlevini kullanıyorum.

sub cmpfunc { 
    return ($a->[0] <=> $b->[0]) or 
      ($a->[1] <=> $b->[1]) or 
      ($a->[2] <=> $b->[2]); 
} 
my @B = sort cmpfunc @A; 
print "Result:\n"; 
for my $element (@B) { 
    print join(",", @{$element}) . "\n"; 
} 

Sonuç:

1,2,3 
1,0,2 
2,3,1 
2,2,4 
3,1,2 

sonuç biraz sınıflandırılır ancak doğru değildir. Beklediğim şey:

1,0,2 
1,2,3 
2,2,4 
2,3,1 
3,1,2 

Karşılaştırma işlevimde herhangi bir hata var mı? Tuhaf olan şey, karşılaştırma kodunu blokta koyduğumda, sonuç doğru şekilde sıralanıyor. Bunu "veya" arasındaki maddelerden herhangi birine girmeden önce döner

return ($a->[0] <=> $b->[0]) 

yürütme

sub cmpfunc { 
    return (($a->[0] <=> $b->[0]) or 
      ($a->[1] <=> $b->[1]) or 
      ($a->[2] <=> $b->[2])); 
} 

Answer 1

:

my @C = sort { ($a->[0] <=> $b->[0]) or 
       ($a->[1] <=> $b->[1]) or 
       ($a->[2] <=> $b->[2]) } @A; 

Answer 2

daha parantez ihtiyacı var.

Ya "dönüş" anahtar kelime kaldırma veya geri dönüşü için tüm arg listeye etrafında parantez ekleyin:

sub cmpfunc { 
    return(($a->[0] <=> $b->[0]) or 
      ($a->[1] <=> $b->[1]) or 
      ($a->[2] <=> $b->[2])); 
} 

Answer 3

bu "yanlış" davranışı gözlemlemek nedeni or operatör, en düşük öncelikli olan mümkün. Saçma sapan bu durumda, dönüş döndürür asla - Bu durumda bu

return ($a->[0] <=> $b->[0]) or 
     ($a->[1] <=> $b->[1]) or 
     ($a->[2] <=> $b->[2]); 

olarak yorumlanır YA-ing

return ($a->[0] <=> $b->[0]) 

ve hattın kalanını demektir. :)

Yani C'nin OR kullanmalıdır:

return ($a->[0] <=> $b->[0]) || 
     ($a->[1] <=> $b->[1]) || 
     ($a->[2] <=> $b->[2]); 

Answer 4

sub cmpfunc { 
    return ($a->[0] <=> $b->[0]) or 
      ($a->[1] <=> $b->[1]) or 
      ($a->[2] <=> $b->[2]); 
} 

sen 'dönüşü' silebilirsiniz burada.

sub cmpfunc { 
    ($a->[0] <=> $b->[0]) or 
    ($a->[1] <=> $b->[1]) or 
    ($a->[2] <=> $b->[2]); 
} 

Answer 5

Daniel'in bir alternatif çözüm:

sub cmpfunc { 
    return ($a->[0] <=> $b->[0]) || 
      ($a->[1] <=> $b->[1]) || 
      ($a->[2] <=> $b->[2]); 
} 

or bu durumda sorun o yüzden işlevi yalnızca -1 ($a->[0] <=> $b->[0]) sonucunu döndürür, atama daha düşük önceliğe sahip olmasıdır, 0 veya 1 ise, sol taraf sırasıyla, sağ tarafa eşit veya ondan daha büyükse.|| daha yüksek önceliğe sahiptir, bu nedenle, tüm boole ifadesi geri dönmeden önce değerlendirilir. Belirtildiği gibi, ||'a tercih ederseniz, ifadeyi parantez içine alabilirsiniz. Şahsen ben yok.