İki tarih arasındaki iş günlerinin sayısı nasıl hesaplanır?

Question

Belirtilen tarihler arasında iş günlerinin sayısını (iş günü) hesaplamam gerekiyor. İş günleri, cumartesi ve pazar günleri hariç haftanın tüm günleridir. Bu sayıma tatiller düşünmüyorum.

İki tarih arasındaki iş günlerinin sayısı nasıl hesaplanır?

Answer 1

DayOfTheWeek (DateUtils biriminden) ve başlangıç ​​tarihinden bitiş tarihine kadar yinelenen bir sayaç kullanmanız gerekir. (Ayrıca muhtemelen de sayımı gelenler dışlamak için, bayramların bir tablo gerekir.) Diğer bir deyişle parametrelerin sırayla (endişesi vermeyerek bu biraz artırabilir

function BusinessDaysBetween(const StartDate, EndDate: TDateTime): Integer; 
var 
    CurrDate : TDateTime; 
begin 
    CurrDate := StartDate; 
    Result := 0; 
    while (CurrDate <= EndDate) do 
    begin 
    // DayOfTheWeek returns 1-5 for Mon-Fri, so 6 and 7 are weekends 
    if DayOfTheWeek(CurrDate) < 6 then 
     Inc(Result); 
    CurrDate := CurrDate + 1; 
    end; 
end; 

, Götürmezse 't) uç veya son başlamadan önce önce başlangıç ​​ise, fonksiyon çalışmaya devam eder matter:

function BusinessDaysBetween(const FirstDate, SecondDate: TDateTime): Integer; 
var 
    CurrDate : TDateTime; 
    StartDate, EndDate: TDateTime; 
begin 
    if SecondDate > FirstDate then 
    begin 
    StartDate := FirstDate; 
    EndDate := SecondDate; 
    end 
    else 
    begin 
    StartDate := SecondDate; 
    EndDate := FirstDate; 
    end; 

    CurrDate := StartDate; 
    Result := 0; 

    while (CurrDate <= EndDate) do 
    begin 
    if DayOfTheWeek(CurrDate) < 6 then 
     Inc(Result); 
    CurrDate := CurrDate + 1; 
    end; 
end; 

Answer 2

her gün ve her giriş parametreleri sırasına bağlı değildir döngü olmadan.

Uses DateUtils,Math; 

function WorkingDaysBetween(const firstDate,secondDate : TDateTime) : Integer; 
var 
    startDate,stopDate : TDateTime; 
    startDow,stopDow : Integer; 
begin 
    if (firstDate < secondDate) then 
    begin 
    startDate := firstDate; 
    stopDate := secondDate; 
    end 
    else 
    begin 
    startDate := secondDate; 
    stopDate := firstDate; 
    end; 
    startDow := DayOfTheWeek(startDate); 
    stopDow := DayOfTheWeek(stopDate); 
    if (stopDow >= startDow) then 
    stopDow := Min(stopDow,6) 
    else 
    Inc(stopDow,5); 

    Result := 
    5*WeeksBetween(stopDate,startDate) + 
    (stopDow - Min(startDow,6)); 
end; 

Answer 3

function BusinessDaysSinceFixedDate (const nDate : tDateTime) : integer; 
const 
    Map : array [ -6 .. 6 ] of integer 
     = ( 0, 0, 1, 2, 3, 4, 5, 5, 5, 6, 7, 8, 9); 
var 
    X : integer; 
begin 
    X := trunc (nDate); 
    Result := 5 * (X div 7) + Map [ X mod 7 ]; 
end; 

function BusinessDaysBetweenDates (const nStartDate : tDateTime; 
            const nEndDate : tDateTime) : integer; 
begin 
    Result := BusinessDaysSinceFixedDate (nEndDate) 
      - BusinessDaysSinceFixedDate (nStartDate); 
end; 

rutin BusinessDaysSinceFixedDate sabit tarihten itibaren iş günü sayısını hesaplar. İlgili olmayan tarih 25 Aralık 1899 Pazartesi'dir. Sadece geçen hafta sayısını (X div 7) sayar ve bunu 5 ile çarpır. Güne göre düzeltmek için bir ofset ekler. haftanın. (X mod 7) negatif tarih için negatif bir değer döndürür Not, 30 Aralık önce, yani, bir tarih, 1899

sadece başlangıç ​​ve bitiş tarihi BusinessDaysSinceFixedDate aramalar ve diğer bir çıkarır rutin BusinessDaysBetweenDates.