Haskell komut satırı uygulaması

Question

aşağıdaki Haskell programı bir şifre sormak terminalde bir parola ister ve o doğru olanı girmiş devam eder:

main = do 
    putStrLn "Password:" 
    password <- getLine 

    case hash password `member` database of 
     False -> putStrLn "Unauthorized use!" 
     True -> do 
       ... 

Maalesef şifre görünecektir Ekranı kullanıcı olarak yazdığı gibi, kaçınmak istiyorum.

Kullanıcıların ekranda görünmeden yazdığı karakter dizisini nasıl okuyabilirim? Bu amaç için getLine eş değeri nedir?

MacOS X'tayım, ancak bunun Windows ve Linux'ta da çalışmasını istiyorum.

Answer 1

sonraki deneyin:

module Main 
where 

import System.IO 
import Control.Exception 

main :: IO() 
main = getPassword >>= putStrLn . ("Entered: " ++) 

getPassword :: IO String 
getPassword = do 
    putStr "Password: " 
    hFlush stdout 
    pass <- withEcho False getLine 
    putChar '\n' 
    return pass 

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = do 
    old <- hGetEcho stdin 
    bracket_ (hSetEcho stdin echo) (hSetEcho stdin old) action 

Answer 2

Terminalde yankılanmayı the System.Posix.Terminal module ile devre dışı bırakmak mümkündür. Ancak, bu POSIX desteği gerektirir, bu nedenle Windows üzerinde çalışmayabilir (ben kontrol etmedim). Stdin hattı tamponlu, yani putStr "Password:" yerine putStrLn kullanmak, aksi istemi de inhibe edilecek birinci tampon temizleme için gereken

import System.Posix.Terminal 
import System.Posix.IO (stdInput) 

getPassword :: IO String 
getPassword = do 
    tc <- getTerminalAttributes stdInput 
    setTerminalAttributes stdInput (withoutMode tc EnableEcho) Immediately 
    password <- getLine 
    setTerminalAttributes stdInput tc Immediately 
    return password 

main = do 
    putStrLn "Password:" 
    password <- getPassword 
    putStrLn "Name:" 
    name <- getLine 
    putStrLn $ "Your password is " ++ password ++ " and your name is " ++ name 

not edin.

Answer 3

System.Console.Haskeline bir getPassword yoktur. Muhtemelen senin durumun için bir overkill ama birisi yararlı bulabilir.

Bir örnek: Yukarıda yorumladığı gibi

> runInputT defaultSettings $ do {p <- getPassword (Just '*') "pass:"; outputStrLn $ fromJust p} 
pass:*** 
asd 

Answer 4

, sana tam bir istemi kütüphane olduğunu haskeline, kullanmanızı öneririz. Hiçbir şikayeti olmadan LambdaCalculator için mutlu bir şekilde kullandım.

Answer 5

withEcho biraz daha az noice ile yazılabilir:

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = 
    bracket (hGetEcho stdin) 
      (hSetEcho stdin) 
      (const $ hSetEcho stdin echo >> action)