'org.sonarqube' kimliğine sahip eklenti bulunamadı

Question

Projem için kod kapsamı ölçüsü için sonar kürsüsü kullanmaya çalışıyorum. gradle-4.0.1 ve sonarqube-6.4 kullanıyoruz. Ben komut satırından gradle sonarqube çalıştırdığınızda

bu ben kaç kod değişiklikleri çalıştı ama hiçbir şans, lütfen yardım

Plugin with id 'org.sonarqube' not found. 

hatasız olsun. Benim build.gradle dosyası Hemen 'org.springframework.boot' eklentisi gibi

buildscript { 
    ext { 
     springBootVersion = '1.5.4.RELEASE' 
    } 
    repositories { 
     mavenCentral() 
    } 
    dependencies { 
     classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}") 
    } 
} 

apply plugin: 'org.sonarqube' 
apply plugin: "jacoco" 
apply plugin: "java" 
apply plugin: "war" 
apply plugin: "org.springframework.boot" 


sonarqube { 
    properties { 
    property "sonar.projectName","Spring4WebService Code Coverage Demo" 
    property "sonar.projectKey", "org.sonarqubeJacocoCodeCoverage" 
    property "sonar.reportPath" , "${project.buildDir}/jacoco/test.exec" 
    } 
} 


test{ 
    ignoreFailures = true 
} 


ext { 
    jacocoVersion = '0.7.6.201602180812' 
} 

sourceCompatibility = 1.8 
targetCompatibility = 1.8 

repositories { 
    mavenCentral() 
} 


sourceSets { 
    main.java.srcDir "src/main/java" 
    test.java.srcDir "src/test/java" 
} 

springBoot { 
    mainClass = "com.concretepage.config.WebAppInitializer" 
} 

dependencies { 
    compile('org.springframework.boot:spring-boot-starter-web','com.fasterxml.jackson.core:jackson-databind') 
    testCompile('org.springframework.boot:spring-boot-starter-test') 
} 

jacoco{ 
    toolVersion = "${jacocoVersion}" 
} 

jacocoTestReport { 
reports{ 
    html.enabled=true 
    xml.enabled=true 
    csv.enabled=true 
} 
} 

Answer 1

aşağıda- gibidir, 'org.sonarqube' eklentisi Gradle ait değil. Bu bir üçüncü taraf eklenti, yani bir buildscript bağımlılık olarak eklemek gerekir:

buildscript { 
    ext { 
     springBootVersion = '1.5.4.RELEASE' 
    } 
    repositories { 
     mavenCentral() 
     maven { 
      url "https://plugins.gradle.org/m2/" 
     } 
    } 
    dependencies { 
     classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}") 
     classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:2.5" 
    } 
} 

Şimdi apply plugin: 'org.sonarqube' iyi çalışması gerekir.