Grafiği resimli olarak gönder - bir butona tıklayarak tıklayın

Question

Grafik "jpeg dosyası" olarak bir tabloyu dışa aktaracak bir düğme oluşturmaya çalışıyorum. Bu aldığım kodu ancak bu hatayı gösteren devam ediyor: Bunun Özellikle

runtime error 424: object required

:

Set myChart = Graphs.ChartObjects(3).Name = "Chart4" 

Ve burada kod

Sub ExportChart() 
    Dim myChart As Chart 
    Dim myFileName As String 
    Set myChart = Graphs.ChartObjects(3).Name = "Chart4" 
    myFileName = "myChart.jpg" 
    On Error Resume Next 
    Kill ThisWorkbook.Path & "\" & myFileName 
    myChart.Export Filename:=ThisWorkbook.Path & "\" & myFileName, Filtername:="PNG" 
    MsgBox "OK" 
    Set myChart = Nothing 
End Sub 

herkese teşekkürler bu!

Answer 1

Denediğin şey bu mu?

Ayrıca jpg olarak kaydetmeye çalışıyorsanız, neden bir png filtresi? "MyChart.jpg" yi "myChart.png" olarak değiştirdim. Uygulanabilir olarak değiştirin.

Sub ExportChart() 
    Dim objChrt As ChartObject 
    Dim myChart As Chart 

    Set objChrt = Sheets("Graphs").ChartObjects(3) 
    Set myChart = objChrt.Chart 

    myFileName = "myChart.png" 

    On Error Resume Next 
    Kill ThisWorkbook.Path & "\" & myFileName 
    On Error GoTo 0 

    myChart.Export Filename:=ThisWorkbook.Path & "\" & myFileName, Filtername:="PNG" 

    MsgBox "OK" 
End Sub 

Answer 2

Teşekkürler, ben görüntünün tüm grafikleri ayıklamak için bu gerekli ve neredeyse gece yarısı. Yukarıdaki kodda yapılan küçük değişiklikler hile yaptı.

Sub ExportChart() 
    Dim WS As Excel.Worksheet 
    Dim SaveToDirectory As String 

    Dim objChrt As ChartObject 
    Dim myChart As Chart 

    SaveToDirectory = ActiveWorkbook.Path & "\" 

    For Each WS In ActiveWorkbook.Worksheets 
     WS.Activate 'go there 
     For Each objChrt In WS.ChartObjects 
      objChrt.Activate 
      Set myChart = objChrt.Chart 

      myFileName = SaveToDirectory & WS.Name & "_" & objChrt.Index & ".png" 

      On Error Resume Next 
      Kill SaveToDirectory & WS.Name & Index & ".png" 
      On Error GoTo 0 

      myChart.Export Filename:=myFileName, Filtername:="PNG" 
     Next 
    Next 

    MsgBox "OK" 
End Sub