Vim durum satırı rengini nasıl değiştirebilirim?

Question

Vim durum çizgisi rengini .vimrc düzenleyerek değiştirmeyi tercih ediyorum.

au komutunu kullanarak, ekleme moduna girerken veya çıkarken durum satırının rengini değiştirmeye çalıştım; Bu komut bir şey kullanarak gerçekleşir:

hi StatusLine guibg=whatevercolourIwant

herhangi au komutu olmadan doğrudan statü çizgi rengi değiştirerek, arka plan aynı kalır. Örneğin

:hi StatusLine guibg=red,

yürüterek, durum çubuğunun arka plan hala yeşilimsi kalır neden

sebep var mı?

hi StatusLine ctermbg=whatever ctermfg=whatever 

guibg guifg GUI içindir: Eğer terminalde vim çalıştırıyorsanız

Answer 1

, deneyin.

umarım yardımcı olur.

Answer 2

Ben diğer çerez arasında, varım hangi modda bağlı çizginin rengini değiştirir benim durum satırında, bu kullanın:

function! InsertStatuslineColor(mode) 
    if a:mode == 'i' 
    hi statusline guibg=Cyan ctermfg=6 guifg=Black ctermbg=0 
    elseif a:mode == 'r' 
    hi statusline guibg=Purple ctermfg=5 guifg=Black ctermbg=0 
    else 
    hi statusline guibg=DarkRed ctermfg=1 guifg=Black ctermbg=0 
    endif 
endfunction 

au InsertEnter * call InsertStatuslineColor(v:insertmode) 
au InsertLeave * hi statusline guibg=DarkGrey ctermfg=8 guifg=White ctermbg=15 

" default the statusline to green when entering Vim 
hi statusline guibg=DarkGrey ctermfg=8 guifg=White ctermbg=15 

" Formats the statusline 
set statusline=%f       " file name 
set statusline+=[%{strlen(&fenc)?&fenc:'none'}, "file encoding 
set statusline+=%{&ff}] "file format 
set statusline+=%y  "filetype 
set statusline+=%h  "help file flag 
set statusline+=%m  "modified flag 
set statusline+=%r  "read only flag 

" Puts in the current git status 
    if count(g:pathogen_disabled, 'Fugitive') < 1 
     set statusline+=%{fugitive#statusline()} 
    endif 

" Puts in syntastic warnings 
    if count(g:pathogen_disabled, 'Syntastic') < 1 
     set statusline+=%#warningmsg# 
     set statusline+=%{SyntasticStatuslineFlag()} 
     set statusline+=%* 
    endif 

set statusline+=\ %=      " align left 
set statusline+=Line:%l/%L[%p%%]   " line X of Y [percent of file] 
set statusline+=\ Col:%c     " current column 
set statusline+=\ Buf:%n     " Buffer number 
set statusline+=\ [%b][0x%B]\    " ASCII and byte code under cursor 

Answer 3

Bu gerçekten bir kod müthiş biraz !!

Gereksinimlerime uyacak şekilde değiştirdim. Arabellek durumu için bazı ifadeleri ekledim:

[Kayıtlı] veya [değiştirildi].

Durum çubuğu rengimi arabellek değişimi olayı temelinde ayarlıyorum. Değişmeyen/normal için DarkSlateGray. Herhangi bir değişiklik yapıldıysa OrangeRed4. İşte

benim değiştirilmiş kodu:

" Some funky status bar code its seems 
" https://stackoverflow.com/questions/9065941/how-can-i-change-vim-status-line-colour 
set laststatus=2   " set the bottom status bar 

function! ModifiedColor() 
    if &mod == 1 
     hi statusline guibg=White ctermfg=8 guifg=OrangeRed4 ctermbg=15 
    else 
     hi statusline guibg=White ctermfg=8 guifg=DarkSlateGray ctermbg=15 
    endif 
endfunction 

au InsertLeave,InsertEnter,BufWritePost * call ModifiedColor() 
" default the statusline when entering Vim 
hi statusline guibg=White ctermfg=8 guifg=DarkSlateGray ctermbg=15 

" Formats the statusline 
set statusline=%f       " file name 
set statusline+=[%{strlen(&fenc)?&fenc:'none'}, "file encoding 
set statusline+=%{&ff}] "file format 
set statusline+=%y  "filetype 
set statusline+=%h  "help file flag 
set statusline+=[%{getbufvar(bufnr('%'),'&mod')?'modified':'saved'}]  
"modified flag 

set statusline+=%r  "read only flag 

set statusline+=\ %=      " align left 
set statusline+=Line:%l/%L[%p%%]   " line X of Y [percent of file] 
set statusline+=\ Col:%c     " current column 
set statusline+=\ Buf:%n     " Buffer number 
set statusline+=\ [%b][0x%B]\    " ASCII and byte code under cursor