geliyor) Çizilen verinin boyutlarını ayarlayın. İşte yapan bir komut dosyası şudur: Bu örnek veriler için
#!/usr/bin/env gnuplot
# don't make any output just yet
set terminal unknown
# plot the data file to get information on ranges
plot 'data.dat' title 'My Moneys'
# span of data in x and y
xspan = GPVAL_DATA_X_MAX - GPVAL_DATA_X_MIN
yspan = GPVAL_DATA_Y_MAX - GPVAL_DATA_Y_MIN
# define the values in x and y you want to be one 'equivalent:'
# that is, xequiv units in x and yequiv units in y will make a square plot
xequiv = 100
yequiv = 250
# aspect ratio of plot
ar = yspan/xspan * xequiv/yequiv
# dimension of plot in x and y (pixels)
# for constant height make ydim constant
ydim = 200
xdim = 200/ar
# set the y tic interval
set ytics 100
# set the x and y ranges
set xrange [GPVAL_DATA_X_MIN:GPVAL_DATA_X_MAX]
set yrange [GPVAL_DATA_Y_MIN:GPVAL_DATA_Y_MAX]
# set the labels
set title 'Dollars in buckets'
set xlabel 'number'
set ylabel 'Dollars'
set terminal png size xdim,ydim
set output 'test.png'
set size ratio ar
set style data linespoints
replot
:
0 50
50 150
100 400
150 500
200 300
alıyorum aşağıdaki arsa: olması gerektiği gibi
Bu meydanda hakkındadır be (ben x cinsinden 100 birime eşit olacak şekilde tanımladım, ve veriler [(0,200), (50,500)] aralığını kapsamaktadır. Başka bir veri noktası (400300) eklerseniz, çıkış dosyası beklendiği gibi geniştir:
diğer soruyu cevaplamak için, böylece y tik artışı ayarlayabilirsiniz:
set ytics <INCREMENT>
Yukarıdaki betik bir örnek verir.
Yan not: terminal komutunun boyutunun tanımlanması ('set terminal png size ...'), gerçek çıktı dosyasının boyutunu tanımlar ve 'set boyut oranı', çıktı içindeki alanın en boy oranını ayarlar arsa nerede çizilir. En boy oranının tutarlı olmasını sağlamak için ikisini de yaptım. –
andyras